**Appendix: Listings of pulse programs**

All pulse programs listed in this appendix were run on a Bruker DRX-700 spectrometer equipped with 1.7 mm and 1.0 mm TXI microprobes and the Topspin 1.3 software package.

**Listing 1: Experiment to optimize water flip-back pulses**

;Pulse program for optimizing the 90 deg. soft pulses flip up "FLIPU" and flip down "FLIPD".

;The "FLIPD" version is a 1D experiment for large proteins.

;use the gs mode to adjust the soft pulses

;pl1: high power level

;sp2: power level for flip down soft pulse

;sp3: power level for flip up soft pulse

;spnam2: Gaussian, 128 pnts, 5% trunc.

;spnam3: Gaussian, 128 pnts, 5% trunc.

;p1: 90 deg 1H pulse with power pl1

;p11: length of the soft pulse

;phcor2: phase correction flip down

;phcor3: phase correction flip up

;p21: length of gradient pulse (set to 500u)

;gpz1: 45%

;gpnam1: SINE.32

;Use ZGOPTNS in ased to define the flags. eg -DFLIPD

;#define FLIPD ;flip down soft pulse

;#define FLIPU ;flip up soft pulse

#include <Avance.incl>

1 ze

10u

2 10u

10u

d1

10u

10u pl1:f1

10u LOCKH\_ON

p21:gp1

5m

10u LOCKH\_OFF

#ifdef FLIPD

(p11:sp2 ph2:r):f1

6u

4u pl1:f1

#endif

(p1 ph1):f1

#ifdef FLIPU

10u

(p11:sp3 ph3:r):f1

10u

#endif

go=2 ph0

10m wr #0

10u do:f1

exit

ph1=0 1 2 3

ph2=2 3 0 1

ph3=2 3 0 1

ph0=0 1 2 3

**Listing 2: 2D [15N,1H]-TROSY experiment**

;Pulse program for the measurement of 2D [15N,1H]-TROSY spectra.

;References:

;K. Pervushin et al., PNAS, 94, 12366 (1997)

;K. Pervushin et al., J. Biomol. NMR, 12, 345 (1998)

;Zhang et al, JACS, 130, 7357 (2008)

;carrier positions [ppm]: 1H 4.7, 13C 110, 15N 118

;ZGOPTNS: -Ddec13C for 13C decoupling

;pl1 : power for 1H

;pl2 : power for 13C

;pl3 : power for 15N

;sp1 : 1H wg (ph26)

;sp3 : 1H flip up (ph3,25,27,28)

;spnam1: Gaussian, 128 pnts, 5% trunc.

;spnam3: Gaussian, 128 pnts, 5% trunc.

;p1 : 90 degree hard pulse 1H

;p3 : 90 degree hard pulse 13C

;p4 : 180 degree hard pulse 13C (225d for 5/600)

;p5 : 90 degree hard pulse 15N

;p11 : water flipback pulse (1.1m)

;p21 : 500u (Gradient in first INEPT)

;p22 : 500u (Gradient in second INEPT)

;p23 : 900u (Gradient in watergate)

;gpz1 : 19%

;gpz2 : 15%

;gpz3 : 32%

;gpnam1: SINE.32

;gpnam2: SINE.32

;gpnam3: SINE.32

;d1 : relaxation delay

;d2 : INEPT delay (~2.7ms)

;in0 : 1/(2 SW) (Hz)

;cnst4 : p4/p3 ratio (~2.5 for <700 Mhz)

#include <Avance.incl>

#include <Delay.incl>

;#define dec13C

#define GRADIENT1 10u p21:gp1 200u

#define GRADIENT2 10u p22:gp2 200u

#define GRADIENT3 10u p23:gp3 200u

"in0=inf1/2"

"p2=p1\*2"

"p4=p3\*cnst4"

"p6=p5\*2"

#ifdef dec13C

"d0=in0/2-p5\*2/3.14159-(p3+p4/2 + 1.5u)"

#else

"d0=in0/2-p5\*2/3.14159"

#endif

"TAU1=d2-(p21+p11+210u)-10u"

"TAU2=d2-(p22+p11+210u)-10u"

"TAU3=d2-(p23+p11+210u)-10u"

"l1 = 1"

1 10u ze

2 1m

d1

20u pl1:f1

20u pl2:f2

20u pl3:f3

20u LOCKH\_ON

;----------------------------------------first INEPT

5 10u

(p1 ph20):f1

10u

(p11:sp3 ph25:r):f1

GRADIENT1

TAU1 pl1:f1

(center(p2 ph21):f1 (p6 ph20):f3)

GRADIENT1

TAU1

(p11:sp3 ph27:r):f1

5u 5u pl1:f1

(p1 ph23):f1

;----------------------------------------15N evolution

if "l1 %2 == 1"

{

(p5 ph1):f3

}

else

{

(p5 ph11):f3

}

d0

#ifdef dec13C

(p3 ph23 1.5u p4 ph20 1.5u p3 ph23):f2

#endif

d0

;----------------------------------------ST2PT

(p1 ph2):f1

10u

(p11:sp3 ph3:r):f1

GRADIENT2

TAU2 pl1:f1

(center(p2 ph20):f1 (p6 ph20):f3)

GRADIENT2

TAU2

(p11:sp3 ph28:r):f1

5u 5u pl1:f1

(center(p1 ph20):f1 (p5 ph4):f3)

GRADIENT3

TAU3

(p11:sp1 ph26:r):f1

5u 5u pl1:f1

(center(p2 ph20):f1 (p6 ph20):f3)

5u 5u

(p11:sp1 ph26:r):f1

GRADIENT3

TAU3 LOCKH\_OFF

(p5 ph20):f3

;----------------------------------------acquisition

go=2 ph31

1m mc #0 to 2 F1EA(ip2\*2 & ip3\*2 & ip4\*2 & iu1,id0)

10u do:f1

10u do:f2

10u do:f3

10u ;do:f4

10u LOCKH\_OFF

exit

ph1 =1 3 2 0

ph11=1 3 0 2

ph2 =3 3 3 3

ph3 =1 1 1 1

ph4 =3 3 3 3

ph20=0

ph21=1

ph22=2

ph23=3

ph25=2

ph26=2

ph27=3

ph28=0

ph31=1 3 2 0

**Listing 3: 1H-TRO-STE Experiment**

; Pulse program to measure the translational diffusion coefficient of a 15N-

;labeled protein.

;Literature:

;Horst et al. JACS 133, 16354-16357 (2011).

;Start experiment using Bruker standard AU macro <dosy>

;Use AU-program dosy to calculate gradient ramp-file Difframp OR

;use predefined ramp-file (see ZGOPTNS).

;ZGOPTNS: -DRAMPFILE for non-standard Difframp file

;carrier positions [ppm]: 1H 4.7, 15N 118

;pl1 : power for 1H

;pl3 : power for 15N

;sp1 : 1H flip down (ph11,ph13)

;sp2 : 1H flip up (ph12)

;spnam1: Gaussian, 128 pnts, 5% trunc.

;spnam2: Gaussian, 128 pnts, 5% trunc.

;p1 : 90 degree hard pulse 1H

;p5 : 90 degree hard pulse 15N

;p11 : water flipback pulse [1.1m]

;p21 : spoil gradient [0.6 ms]

;p30 : gradient pulse (little DELTA)

;d1 : relaxation delay

;d2 : half the transfer time (1/4J)

;d16 : gradient recovery [0.4 ms]

;d20 : diffusion time (big DELTA)

#include <Avance.incl>

#include <Grad.incl>

#include <Delay.incl>

#define GRAD1 p21:gp1 d16

#define GRAD\_D p30:gp6\*diff d16

#ifndef RAMPFILE

#define GRADLIST Difframp

#endif

#ifdef RAMPFILE

#define GRADLIST Difframp2\_95.rh

#endif

"DELTA=d20-d2\*2-p1\*2-p11\*2-p21-d16-10u"

"TAU=d2\*2-p30-d16-4u"

define list<gradient> diff=<Difframp>

1 10u ze

2 30m

10u do:f3

d1

50u UNBLKGRAD

10u pl1:f1

10u pl3:f3

;----------------------------------------[H,HNz]-CRINEPT

(p11:sp1 ph11:r):f1

4u

6u pl1:f1

(p1 ph20):f1

GRAD\_D

TAU 4u

(p1 ph20 10u p11:sp2 ph12:r):f1 (p5 ph1 2u p5 ph20):f3

;----------------------------------------diffusion delay

GRAD1

DELTA

(p11:sp1 ph13:r):f1

4u

6u pl1:f1

(p1 ph2):f1

;----------------------------------------[HNz,H]-CRINEPT

GRAD\_D

TAU

4u BLKGRAD

;----------------------------------------acquisition

go=2 ph31

30m mc #0 to 2 F1QF(igrad diff)

exit

ph1 = 0 2 0 2

ph2 = 0 0 1 1

ph11= 2

ph12= 2

ph13= 2 2 3 3

ph31= 0 2 2 0

ph20=0

ph21=1

ph22=2

ph23=3

**Listing 4: TRACT Experiment**

;Pulse program for the determination of the effective rotational

;correlation time of a 15N-labeled protein

;Literature:

;Lee et al. JMR, 178, 72-76 (2006)

;carrier positions [ppm]: 1H 4.7, 13C 110, 15N 118

;pl1 : power for 1H

;pl2 : power for 13C

;pl3 : power for 15N

;sp1 : 1H wg (ph26)

;sp3 : 1H flip up (ph3,25,27,28)

;spnam1: Gaussian, 128 pnts, 5% trunc.

;spnam2: Gaussian, 128 pnts, 5% trunc.

;p1 : 90 degree hard pulse 1H

;p3 : 90 degree hard pulse 13C

;p5 : 90 degree hard pulse 15N

;p11 : water flipback pulse (1.1m)

;p50 : 1m (Gradient for cleaning)

;p51 : 500u (Gradient in first INEPT)

;p52 : 500u (Gradient in second INEPT)

;p53 : 900u (Gradient in watergate)

;p54 : 500u (Gradient z-filter)

;gpz0 : 80%

;gpz1 : 19%

;gpz2 : 15%

;gpz3 : 32%

;gpz4 : 60%

;d0 : relaxation delay (start value)

;d1 : recovery delay

;d2 : INEPT delay (~2.7ms)

;in0 : 1/2 increment of d0

;cnst4 : p4/p3 ratio (~2.5 for <700 MHz, 2.0 otherwise)

#include <Avance.incl>

#include <Delay.incl>

#include <Grad.incl>

;define dec13C

#define GRAD0 10u p50:gp0 200u

#define GRAD1 10u p51:gp1 200u

#define GRAD2 10u p52:gp2 200u

#define GRAD3 10u p53:gp3 200u

#define GRAD4 10u p54:gp4 200u

"p2=p1\*2"

"p4=p3\*cnst4"

"p6=p5\*2"

"d0 = 1u"

"TAU1=d2-(p21+p11+210u)-10u"

"TAU2=d2-(p22+p11+210u)-10u"

"TAU3=d2-(p23+p11+210u)-10u"

"l2 = 1"

1 10u ze

2 1m

10u BLKGRAD

d1

20u pl1:f1

20u pl2:f2

20u pl3:f3

20u UNBLKGRAD

(p5 ph20):f3

GRAD0

1m

;----------------------------------------first INEPT

5 10u

(p1 ph20):f1

10u

(p11:sp3 ph25:r):f1

GRAD1

TAU1 pl1:f1

(center(p2 ph21):f1 (p6 ph20):f3)

GRAD1

TAU1

(p11:sp3 ph27:r):f1

10u

(p1 ph23):f1

GRAD4

;----------------------------------------15N evolution

if "l2 %2 == 1" goto 31

(p5 ph11):f3

goto 32

31 (p5 ph1):f3

32 d0

#ifdef dec13C

(center (p3 ph23 1.5u p4 ph20 1.5u p3 ph23):f2 (p6 ph20):f3)

#else

(p6 ph20):f3

#endif

d0

;----------------------------------------ST2PT

(p1 ph2):f1

10u

(p11:sp3 ph3:r):f1

GRAD2

TAU2 pl1:f1

(center(p2 ph20):f1 (p6 ph20):f3)

GRAD2

TAU2

(p11:sp3 ph28:r):f1

10u

(center(p1 ph20):f1 (p5 ph4):f3)

;----------------------------------------WATERGATE

GRAD3

TAU3

(p11:sp1 ph26:r):f1

10u

(center(p2 ph20):f1 (p6 ph20):f3)

10u

(p11:sp1 ph26:r):f1

GRAD3

TAU3 LOCKH\_OFF

(p5 ph5):f3

;----------------------------------------acquisition

go=2 ph31

1m mc #0 to 2 F1PH(ip5\*2 & iu2,id0)

10u do:f1

10u do:f2

10u do:f3

;10u do:f4

10u BLKGRAD

exit

ph1 =1 3 2 0

ph11=1 3 0 2

ph2 =3 3 3 3

ph3 =1 1 1 1

ph4 =3 3 3 3

ph5 =2 2 2 2

ph31=1 3 2 0

ph20=0

ph21=1

ph22=2

ph23=3

ph25=2

ph26=2

ph27=3

ph28=0